前邊的例01和例02分別展示了靜態服務器及嵌入式SQLite3服務器的實現方法,例03是命名管道客戶端-服務器,例01中用JSON文件存儲數據(按我的理解,每一個SQLRecord就是一個表格,在存儲的時候多個表格應該需要多個JSON文件取存儲),例02中使用SQLite3數據庫存儲,只需要一個.db3數據庫文件就能存放所有的SQLRecord(表格),例03中實現了客戶端-服務器的通訊,客戶端的數據需要傳遞到服務器去處理.

先看看服務器是怎么運行的,例03主單元Unit2.pas實現了命名管道服務器,在代碼中看比較方便,省略了部分代碼,只看主要的部分:

unit Unit2;
interface
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs,
  // 下方是mORMot單元
  SynCommons, mORMot, mORMotSQLite3, SynSQLite3Static, StdCtrls, SampleData;
type
  TForm1 = class(TForm)
   { ...(省略) }
  public
    Model: TSQLModel; { 聲明SQL操作模型 }
    Server: TSQLRestServerDB; { 服務器的聲明 }
  end;
{ ...(省略) }
implementation
{$R *.dfm}
{ ...(省略) }
procedure TForm1.FormCreate(Sender: TObject);
begin
  Model := CreateSampleModel; { 窗口創建的時候初始化數據庫操作模型 }
  Server := TSQLRestServerDB.Create(Model, ChangeFileExt(ExeVersion.ProgramFileName, '.db3')); { 初始化一個Rest服務器,這里和樣例2是一樣的 }
  Server.CreateMissingTables; { 根據模型Model創建必須的表格(也就是SampleData單元定義的類) }
  Server.ExportServerNamedPipe('03'); { 創建命名管道,名字為03,客戶端初始化的時候必須和此名稱一致才能進行進程間通訊 }
end;
{ ...(省略) }
end.

然后是客戶端部分,這一次我想把SampleData單元進行簡單的改造下,添加一個用戶信息類,用于存儲用戶名和密碼,這樣我們在初始化數據庫的時候會有2個表格SampleRecord和UserInfo,還是看代碼的注釋進行說明:

unit SampleData;
interface
uses
  SynCommons, mORMot;
type
  TSQLSampleRecord = class(TSQLRecord)
  { ...省略 }
  end;

  { 我們再添加一個類,用于記錄用戶名和密碼 }
  TSQLUserInfo = class(TSQLRecord)
  private
    fUserName: RawUTF8;
    fPassWord: RawUTF8;
    fRemark: TSQLSampleRecord;
  published
    property UserName: RawUTF8 read fUserName write fUserName;
    property PassWord: RawUTF8 read fPassWord write fPassWord;
    property Remark: TSQLSampleRecord read fRemark write fRemark;
  end;

function CreateSampleModel: TSQLModel;

implementation

function CreateSampleModel: TSQLModel;
begin
  result := TSQLModel.Create([TSQLSampleRecord, TSQLUserInfo{ 創建模型的時候要加上我們新定義的類 }]);
end;

end.

客戶端同樣需要進行一些改造,我們需要輸入用戶名和密碼信息,然后一同添加到數據庫中,改造后是這個樣子的:

在這里,客戶端的工程單元必須創建客戶端命名管道,并且管道的名字要與服務端保持一致:

{ 創建與服務端一致的客戶端命名管道,以便與服務端通信 }  
Form1.Database := TSQLRestClientURINamedPipe.Create(Form1.Model, '03');

主單元Unit1.pas實現代碼如下:

unit Unit1;
interface
uses
  {$ifdef MSWINDOWS}
  Windows, Messages, Graphics,
  {$endif}
  Classes, SysUtils, Forms, Controls, Dialogs, StdCtrls, SynCommons, SynTable,
  mORMot, SampleData;
type
{ ...省略 }

implementation

{$ifdef FPC}
{$R *.lfm}
{$else}
{$R *.dfm}
{$endif}

procedure TForm1.FormCreate(Sender: TObject);
begin
  Model := CreateSampleModel;  { 調用后SampleRecord和UserInfo同時對數據庫中對應的2個表進行映射 }
end;

procedure TForm1.AddButtonClick(Sender: TObject);
var
  Rec: TSQLSampleRecord;
  UserRec: TSQLUserInfo; { 聲明用戶信息類 }
begin
  Rec := TSQLSampleRecord.Create;
  UserRec := TSQLUserInfo.Create; { 創建實例 }
  try
    Rec.Name := StringToUTF8(NameEdit.Text);
    Rec.Question := StringToUTF8(QuestionMemo.Text);
    Rec.Log := StringToUTF8('added ' + NameEdit.Text + ' ' + QuestionMemo.Text);
    if Database.Add(Rec, true) = 0 then
      ShowMessage('Error adding the data')
    else
    begin
      MemoLog.Lines.Add('Name: ' + NameEdit.Text + ';' + 'Question: ' + QuestionMemo.Text + ';');
      NameEdit.Text := '';
      QuestionMemo.Text := '';
      NameEdit.SetFocus;
    end;
    { 把用戶名和密碼寫進數據庫 }
    UserRec.UserName := StringToUTF8(UserNameEdit.Text);
    UserRec.PassWord := StringToUTF8(PassWordEdit.Text);
    if DataBase.Add(UserRec, true) = 0 then
      ShowMessage('Error adding the data')
    else
    begin
      UserNameEdit.Clear;
      PassWordEdit.Clear;
    end;
  finally
    Rec.Free;
    UserRec.Free;
  end;
end;
{ ...省略 }
end.

需要先啟動服務端,然后再啟動客戶端,同樣寫入3組記錄,然后用sqliteadmin看看數據庫的情況:

數據庫存儲情況如下:

可以看到,和預想的情況一樣,例02和例03不管是在嵌入式數據庫還是客戶端-服務器的設計,除了DataBase初始化的部分有少許不同,其他代碼可以原封不動,感覺很是方便.到這里基本上摸清了例01-例03樣例的目的,就是最基礎的ORM操作,和不同數據存儲的方式使用,對照文檔看一下,確實如文檔所說,作者并沒有夸大框架的功能,但是總感覺不太習慣作者的英語表達方式,不動手實踐,有的東西光看文檔的確能讓人感到迷糊,繼續努力學習.