例01-例04主要講了ORM操作相關的基本知識,例05說的是報表,我們寫東西最終的目的是要展示,從例05的名字就可以看出來,本例是要為我們展示報表,暫且把它翻譯成源碼級的報表吧(用代碼創建報表).這個例子有3個工程文件,SynPdfFormCanvas\SynPdfLayers\TestSQLite3Pages,逐個學習.

1.SynPdfFormCanvas

這個只有工程源碼,我們先運行一下,然后在工程目錄會生成SynPdfFormCanvas.pdf文件,打開看看:

源碼直接生成pdf文檔,對生成的過程源碼,繼續用備注進行說明:

program SynPdfFormCanvas;

{$APPTYPE CONSOLE}

uses
  {$I SynDprUses.inc} // use FastMM4 on older Delphi, or set FPC threads
  SysUtils,
  Math,
  DateUtils,
  SynCommons,
  SynPDF;

const
  // 此單精度浮點數定義的應該PDF的縮放因子,源碼約28倍,
  // 我們改成14看看有什么變化,再改成7看看其變化
  // 其變化是從左下到右上
  PDFFactor: Single = 72.0 / 2.54;
//  PDFFactor: Single = 14;
var
  // PDF引擎的主類,負責處理整個PDF文檔
  obPDF: TPdfDocument;
  // 帶有畫布的窗體對象,用于繪制界面,你可以根據需要創建XObject對象,
  // 然后把它畫在頁面的任何地方
  obFormCanvas: TPdfFormWithCanvas;

begin
  // 實例化TPdfDocument對象
  obPDF := TPdfDocument.Create(false, 0, false);
  // 設置為true以強制pdf 1.5格式，這樣會產生較小的文件
  obPDF.GeneratePDF15File := true;
  // 顧名思義,設置紙張大小為A4
  obPDF.DefaultPaperSize := psA4;
  // 默認頁面及紙張方向,true為橫向
  obPDF.DefaultPageLandscape := false;
  // 壓縮方式, TPdfCompressionMethod = (cmNone, cmFlateDecode);
  obPDF.CompressionMethod := cmFlateDecode;

  // 實例化TPdfFormWithCanvas對象
  obFormCanvas := TPdfFormWithCanvas.Create(obPDF, Trunc(5.0 * PDFFactor), Trunc(5.0 * PDFFactor));
  // 在TPdfFormWithCanvas上呈現obFormCanvas對象,也就是繪制
  obPDF.AddXObject('FORMOBJECT', obFormCanvas);
  // 設置文本的呈現方式
  obFormCanvas.Canvas.SetTextRenderingMode(trFill);
  // 設置字體,大小
  obFormCanvas.Canvas.SetFont('Arial', 10.0, []);
  // 設置線寬
  obFormCanvas.Canvas.SetLineWidth(0.01 * PDFFactor);
  // 以左下角為基點,繪制矩形
  obFormCanvas.Canvas.Rectangle(0.0 * PDFFactor, 0.0 * PDFFactor, 4.9 * PDFFactor, 4.9 * PDFFactor);
  // 描邊
  obFormCanvas.Canvas.Stroke;
  // 在指定的頁面位置顯示文本
  obFormCanvas.Canvas.TextOut(1.0 * PDFFactor, 2.5 * PDFFactor, 'form text');
  // 關閉畫布
  obFormCanvas.CloseCanvas;

  // 向當前文檔中添加一個頁面
  obPDF.AddPage;

  obPDF.Canvas.SetTextRenderingMode(trFill);
  obPDF.Canvas.SetFont('Arial', 10.0, []);
  obPDF.Canvas.SetLineWidth(0.01 * PDFFactor);
  obPDF.Canvas.Rectangle(1.0 * PDFFactor, 1.0 * PDFFactor, 19.0 * PDFFactor, 27.9 * PDFFactor);
  obPDF.Canvas.Stroke;

  obPDF.Canvas.TextOut(2.0 * PDFFactor, 27.0 * PDFFactor, 'XObject form canvas sample');
  // 拉伸指定的對象(通常是圖像)
//  obPDF.Canvas.DrawXObject(2.0 * PDFFactor, 5.0 * PDFFactor, 1.0, 1.0, 'FORMOBJECT');
//  obPDF.Canvas.DrawXObject(10.0 * PDFFactor, 10.0 * PDFFactor, 1.0, 0.5, 'FORMOBJECT');
//  obPDF.Canvas.DrawXObject(8.0 * PDFFactor, 15.0 * PDFFactor, 2.0, 2.0, 'FORMOBJECT');
//  obPDF.Canvas.DrawXObject(2.0 * PDFFactor, 20.0 * PDFFactor, 0.5, 1.0, 'FORMOBJECT');
  // 將pdf文件內容保存到指定的文件
  obPDF.SaveToFile(ChangeFileExt(ExeVersion.ProgramFileName, '.pdf'));

  FreeAndNil(obPDF);
end.